Numerical to words in Numbers spread sheet

vasanth_sac wrote:

no way to convert numerical values to words…

Years ago I saw convoluted ways to do this using formulas.

Here's a script that does it reasonably well.

use framework "Foundation"
use scripting additions
tell front document of application "Numbers"
	tell active sheet
		tell (first table whose selection range's class is range)
			set outStr to ""
			repeat with aCell in cells in (get its selection range)
				set theNumber to value of aCell
				set theInteger to theNumber div 1
				set theWords to my convertNumberToWords(theInteger)
				set theFraction to my convertDecimalToFraction(theNumber)
				set outStr to outStr & theWords & " and " & theFraction & return
			end repeat
		end tell
	end tell
end tell

set the clipboard to outStr

on convertNumberToWords(aNumber)
	tell current application's NSNumberFormatter to ¬
		set resultingText to localizedStringFromNumber_numberStyle_(aNumber, current application's NSNumberFormatterSpellOutStyle)
	return (resultingText as string)
end convertNumberToWords

on convertDecimalToFraction(aNumber)
	set integerPart to (aNumber div 1)
	set fractionPart to (aNumber - integerPart) * 100
	if fractionPart is 0 then
		return "00/100"
	else if fractionPart mod 10 is 0 then
		set fractionPart to fractionPart div 10
		return fractionPart & "/10"
	else
		return fractionPart div 1 & "/100" as text
	end if
end convertDecimalToFraction

1. Copy-paste the above script in Script Editor (in Applications > Utilities).
2. Select the cells with numbers that you want to convert to words.
3. Click the triangle 'run' button in Script Editor.
4. Click once in a top destination cell in a Numbers table.
5. Command-v or Edit > Paste and Match Style to paste.

Here are sample results:

SG